helpers.cmake

Go to the documentation of this file.

 
function(create_meson_stages _file_setup _file_compile _file_install _component _component_title _srcdir _builddir _meson_options _library_mode _output_libraries)
    # Optional indent level
    if(ARGC GREATER 10)
        set(_indent_level "${ARGV10}")
        string(REPEAT "\t" ${_indent_level} _MESON_INDENT_)
    else()
        set(_MESON_INDENT_ "")
    endif()
 
    if(${_library_mode} STREQUAL "static")
        set(_MESON_LIBRARY_TYPE "static")
        list(APPEND _meson_options "-Db_staticpic=true")
    elseif(${_library_mode} STREQUAL "shared")
        set(_MESON_LIBRARY_TYPE "shared")
    else()
        message(FATAL_ERROR "Unknown library mode '${_library_mode}' in create_meson_stages")
    endif()
 
    # Original logic
    set(_MESON_COMPONENT "${_component}")
    set(_MESON_COMPONENT_TITLE "${_component_title}")
    string(APPEND _MESON_STAGE_BUILD "${_component}" "_build")
    string(APPEND _MESON_STAGE_INSTALL "${_component}" "_install")
    set(_MESON_BUILD_DIR "${_builddir}")
    set(_MESON_SRCDIR "${_srcdir}")
    set(_MESON_OUTPUT_LIBRARIES "${_output_libraries}")
    # Enable LTO only on Release and if CMAKE_INTERPROCEDURAL_OPTIMIZATION is set
    if(CMAKE_BUILD_TYPE STREQUAL "Release" AND CMAKE_INTERPROCEDURAL_OPTIMIZATION_RELEASE)
        set(LTO_ENABLED "true")
    else()
        set(LTO_ENABLED "false")
    endif()
 
    list_join(_MESON_OPTIONS "${_meson_options}" " ")
 
    sanitize_for_filename(_MESON_COMPONENT_SAFE "${_component}")
 
    set(_MESON_SETUP_FILE
        "${BUILDMASTER_SCRIPTS_MESON_DIR}/${_MESON_COMPONENT_SAFE}_configure.cmake"
    )
    set(_MESON_COMPILE_FILE
        "${BUILDMASTER_SCRIPTS_MESON_DIR}/${_MESON_COMPONENT_SAFE}_compile.cmake"
    )
    set(_MESON_INSTALL_FILE
        "${BUILDMASTER_SCRIPTS_MESON_DIR}/${_MESON_COMPONENT_SAFE}_install.cmake"
    )
 
    configure_file(
        "${BUILDMASTER_TOOLS_MESON_SRCDIR}/setup.cmake.in"
        "${_MESON_SETUP_FILE}"
        @ONLY
    )
    configure_file(
        "${BUILDMASTER_TOOLS_MESON_SRCDIR}/compile.cmake.in"
        "${_MESON_COMPILE_FILE}"
        @ONLY
    )
    configure_file(
        "${BUILDMASTER_TOOLS_MESON_SRCDIR}/install.cmake.in"
        "${_MESON_INSTALL_FILE}"
        @ONLY
    )
 
    set(${_file_setup} "${_MESON_SETUP_FILE}" PARENT_SCOPE)
    set(${_file_compile} "${_MESON_COMPILE_FILE}" PARENT_SCOPE)
    set(${_file_install} "${_MESON_INSTALL_FILE}" PARENT_SCOPE)
endfunction()