helpers.cmake

Go to the documentation of this file.

 
macro(add_tool srcdir)
    # Optional indent level
    if(${ARGC} GREATER 1)
        set(_indent_level "${ARGV1}")
        string(REPEAT "\t" ${_indent_level} _INDENT_)
    else()
        set(_INDENT_ "")
    endif()
 
    message(STATUS "${_INDENT_}Setting up ${srcdir}")
    add_subdirectory("${CMAKE_CURRENT_LIST_DIR}/${srcdir}")
    include("${CMAKE_CURRENT_LIST_DIR}/${srcdir}/propagate_vars.cmake")
endmacro()
 
 
macro(ensure_extra_tool_is_available tool_name)
    # Append the tool name to the global property BUILDMASTER_PLUGINS_EXTRA
    get_property(available_extra_tools GLOBAL PROPERTY BUILDMASTER_PLUGINS_EXTRA_AVAILABLE)
    list(FIND available_extra_tools "${tool_name}" _found_index)
    if(_found_index EQUAL -1)
        message(FATAL_ERROR "The extra tool '${tool_name}' is not available. Available extra tools are: ${available_extra_tools}")
    endif()
endmacro()
 
 
macro(propagate_vars_extra_tool tool_name)
    # Append the tool name to the global property BUILDMASTER_PLUGINS_EXTRA
    get_property(configured_extra_tools GLOBAL PROPERTY BUILDMASTER_PLUGINS_EXTRA_ENABLED)
    list(FIND configured_extra_tools "${tool_name}" _found_index)
    if(_found_index GREATER -1)
        include(${tool_name}/propagate_vars.cmake)
    endif()
endmacro()
 
 
macro(propagate_all_vars_extra_tools)
    # Get the list of configured extra tools
    get_property(configured_extra_tools GLOBAL PROPERTY BUILDMASTER_PLUGINS_EXTRA_ENABLED)
    foreach(tool_name IN LISTS configured_extra_tools)
        include(${BUILDMASTER_TOOLS_SRCDIR}/extra/${tool_name}/propagate_vars.cmake)
    endforeach()
endmacro()
 
 
macro(configure_extra_tool tool_name)
    # Read the list of already-enabled tools (may be undefined)
    get_property(configured_extra_tools GLOBAL PROPERTY BUILDMASTER_PLUGINS_EXTRA_ENABLED)
 
    # Check if the tool is already registered
    list(FIND configured_extra_tools "${tool_name}" _found_index)
 
    if(_found_index EQUAL -1)
        # Append cleanly using list(APPEND) — works even if the variable is undefined
        list(APPEND configured_extra_tools "${tool_name}")
 
        # Write back to the global property
        set_property(GLOBAL PROPERTY BUILDMASTER_PLUGINS_EXTRA_ENABLED
                    "${configured_extra_tools}")
 
        # Add the tool directory and propagate its variables
        add_subdirectory(${tool_name})
        include(${tool_name}/propagate_vars.cmake)
    endif()
endmacro()